Patrones de Comportamiento


MEMENTO (RECUERDO) Comportamiento de Objetos

Código de Ejemplo
Ejemplo Simple


Namespace Memento.CodigoBasico

    '-----------------------------------------------
    ''' <summary>
    '''     [Patron Memento] - Objeto Cliente que usa el memento
    ''' </summary>
    Public Class MainApp

        '-----------------------------------------------
        ''' <summary>
        '''    Funcion Main de un Proyecto de Consola
        ''' </summary>
        Public Shared Sub main()

            Dim o As Originador
            o = New Originador
            o.Estado = "On"

            ' Store internal state 
            Dim c As Conserje
            c = New Conserje()
            c.Memento = o.ObtenerMemento()

            ' Continue changing originator 
            o.Estado = "Off"

            ' Restore saved state 
            o.RestaurarMemento(c.Memento)

            ' Wait for user 
            Console.Read()

            '----------------------------------------------
            ' Resultado en la consola de la ejecucion de este codigo
            '----------------------------------------------
            '[Originador] - Asignado el Estado = On
            '[Originador] - Obteniendo un Memento:
            '[Originador] - Asignado el Estado = Off
            '[Originador] - Restaurando un Memento:
            '[Originador] - Asignado el Estado = On
            '----------------------------------------------

        End Sub

    End Class
End Namespace







Namespace Memento.CodigoBasico


    '-----------------------------------------------
    ''' <summary>
    '''     [Patron Memento] - Creador - 
    ''' </summary>
    ''' <remarks>    
    '''    Crea un memento que contiene una instantánea de
    '''    su estado interno actual. 
    '''    Usa el memento para volver a su estado anterior.
    '''</remarks>
    Public Class Originador

        '-----------------------------------------------
        ''' <summary> Campo de la clase </summary>
        Private _Estado As String

        '-----------------------------------------------
        ''' <summary>
        '''    Establece / Devuelve el valor del campo de la clase
        ''' </summary>
        Public Property Estado() As String
            Get
                Return _Estado
            End Get
            Set(ByVal value As String)
                _Estado = value
                Console.WriteLine("[Originador] - Asignado el Estado = " + _Estado)
            End Set
        End Property


        '-----------------------------------------------
        ''' <summary>
        '''     Obtiene un memento con los valores de 
        '''     los campos de la clase
        ''' </summary>
        ''' <returns>Un Objeto Memento</returns>
        Public Function ObtenerMemento() As Memento
            Console.WriteLine("[Originador] - Obteniendo un Memento:")
            Return (New Memento(Estado))
        End Function


        '-----------------------------------------------
        ''' <summary>
        '''     Restaura el valor de los campos de la clase
        '''     con un objeto Memento
        ''' </summary>
        ''' <param name="memento"> 
        '''     El memento del que se leen los datos para
        '''     restaurar los valores de los campos de la clase
        ''' </param>
        Public Sub RestaurarMemento(ByVal memento As Memento)
            Console.WriteLine("[Originador] - Restaurando un Memento:")
            Estado = memento.Estado
        End Sub

    End Class
End Namespace







Namespace Memento.CodigoBasico


    '-----------------------------------------------
    ''' <summary>
    '''   [Patron Memento] - Memento - 
    '''   Guarda el estado interno del objeto Creador. 
    ''' </summary>
    ''' <remarks>    
    '''    <para>El memento puede guardar tanta información 
    '''          del estado interno del creador como sea 
    '''          necesario a discreción del creador
    '''    </para>
    '''    <para>Protege frente a accesos de otros objetos que sea 
    '''          no sean el creador. </para>
    '''    <para>Los mementos tienen realmente dos interfaces. </para>
    '''    <para>El Conserje ve una interfaz reducida del Memento 
    '''          -sólo puede pasar el memento a otros objetos-. 
    '''    </para>
    '''    <para>El Creador, por el contrario, ve una interfaz sea 
    '''          amplia, que le permite acceder a todos los datos sea 
    '''          necesarios para volver a su estado anterior. </para>
    '''    <para>Idealmente, sólo el creador que produjo el sea 
    '''          memento estaría autorizado a acceder al estado sea 
    '''          interno de éste.</para>
    ''' </remarks>
    Public Class Memento

        '-----------------------------------------------
        ''' <summary> Valor del Creador que quiero guardar </summary>
        Private _Estado As String

        '-----------------------------------------------
        ''' <summary>
        '''     El Constructor
        ''' </summary>
        ''' <param name="estado"> 
        '''    El valor del creador que quiero guardar </param>
        ''' <remarks></remarks>
        Public Sub New(ByVal estado As String)
            Me._Estado = estado
        End Sub

        '-----------------------------------------------
        ''' <summary>
        '''    Propiedad de solo lectura para recuperar 
        '''    el valor del menmento
        ''' </summary>
        Public ReadOnly Property Estado() As String
            Get
                Return _Estado
            End Get
        End Property

    End Class
End Namespace






Namespace Memento.CodigoBasico


    '-----------------------------------------------
    ''' <summary>
    '''    [Patron Memento] - Conserje (Caretaker) - 
    '''    Es responsable de guardar en lugar seguro el memento
    ''' </summary>
    ''' <remarks>
    '''    Nunca examina los contenidos del memento, 
    '''    ni opera sobre ellos.
    '''</remarks>
    Public Class Conserje


        '-----------------------------------------------
        ''' <summary> Variable local que almacena el memento </summary>
        ''' <remarks> Observa que solo se puede almacenar un memento </remarks>
        Private _objMemento As Memento

        '-----------------------------------------------
        ''' <summary>
        '''    Establece / Recupera el Memento almacenado en esta clase
        ''' </summary>
        ''' <value></value>
        ''' <returns></returns>
        ''' <remarks></remarks>
        Public Property Memento() As Memento
            Get
                Return _objMemento
            End Get
            Set(ByVal value As Memento)
                _objMemento = value
            End Set
        End Property

    End Class
End Namespace


Patrón Memento (Recuerdo)